;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Kauffman's NK Fitness Landscapes
;; Solved by a chosen heuristic search algorithm
;; This prgoram (C) Christopher J Watts, 2011
;; Based on:
;; Kauffman, S (1993) "The Origins of Order"
;; Kauffman, S (1995) "At Home in the Universe"
;; Kauffman, S (2000) "Investigations"
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


extensions [array]

globals [
  mean-fitness
  max-fitness
  initial-mean-fitness
  initial-max-fitness
  
  input-sets
  fitness-tables
  
  probabilities
  order-statistic
  ordered-list
  
  temperature
  
  tabu-list
]

breed [agents agent]

agents-own [
  fitness
  solution
  alt-solution
  alt-fitness
  
  memory
  
  initial-solution
  initial-fitness
]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to setup
  clear-all
  
  setup-nk
  
  set probabilities array:from-list n-values n-nodes [0.5]
  set temperature 10000
  set tabu-list []
  
  create-agents number-of-agents [
    setxy random-xcor random-ycor
    set color red
    
    set solution array:from-list (map [ifelse-value (? > random-float 1) [1] [0] ] (array:to-list probabilities))
    calc-agent-fitness
    set memory []
    if opt-method = "Harmony Social Search" [
      setup-memory-hss
      set solution item 1 (last memory)
      set fitness item 0 (last memory)
    ]
    
    set initial-solution array:from-list array:to-list solution
    set initial-fitness fitness
  ]
  
  set mean-fitness mean [fitness] of agents
  set max-fitness max [fitness] of agents
  set initial-mean-fitness mean-fitness
  set initial-max-fitness max-fitness
  
  setup-plots
  
end

to setup-memory-hss
  repeat memory-length [
    set solution array:from-list (map [ifelse-value (? > random-float 1) [1] [0] ] (array:to-list probabilities))
    calc-agent-fitness
    set memory fput (list fitness (array:from-list array:to-list solution)) memory
    set memory sort-by [(item 0 ?1) <= (item 0 ?2)] memory
  ]
end


to reset-agents
  ; Without defining the NK fitness landscape, set agent population back to their intial starting points.
  clear-all-plots
  ask agents [
    set solution array:from-list array:to-list initial-solution
    set fitness initial-fitness
    set memory []
  ]
  set mean-fitness mean [fitness] of agents
  set max-fitness max [fitness] of agents
  set probabilities array:from-list n-values n-nodes [0.5]
  set temperature 10000
  set tabu-list []
  
  setup-plots
  
end  
 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to setup-NK
  ; Define input nodes for each node
  set input-sets array:from-list n-values n-nodes [array:from-list n-values (k-inputs + 1) [random (n-nodes - 1)]]
  let cur-node 0
  let cur-input 0
  let input-set array:from-list n-values (k-inputs + 1) [0]
  repeat n-nodes [
    set input-set array:item input-sets cur-node
    set cur-input 0
    array:set input-set 0 cur-node ; Each node is an input to itself
    repeat k-inputs [ ; Each node has K inputs which are not itself
      set cur-input cur-input + 1
      if (array:item input-set cur-input) >= cur-node [array:set input-set cur-input ((array:item input-set cur-input) + 1)]
    ]
    set cur-node cur-node + 1
  ]
  
  ; Define fitness table for each node
  set fitness-tables array:from-list n-values n-nodes [array:from-list n-values (2 ^ (k-inputs + 1)) [random-float 1]]
end

to calc-agent-fitness
  let fitness-sum 0
  let cur-node 0
  repeat n-nodes [
    set fitness-sum fitness-sum + 
      array:item (array:item fitness-tables cur-node) (sum n-values (k-inputs + 1) [(array:item solution (array:item (array:item input-sets cur-node) ?)) * (2 ^ ?)])
    
    set cur-node cur-node + 1
  ]
  
  set fitness (fitness-sum / n-nodes)
  ;set fitness ((fitness-sum / n-nodes) / base-max-fitness) ^ 8 ; Lazer & Friedman's definition
  
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to go
  if ticks = max-ticks [ stop ]
  
  if opt-method = "Random-Walk Hill Climb" [ hill-climb ]
  if opt-method = "Cross-Entropy Method" [ cross-entropy-method ]
  if opt-method = "Weighted Probability Vector" [ via-vector ]
  if opt-method = "Simulated Annealing" [ simulated-annealing ]
  if opt-method = "Genetic Algorithm" [ genetic-algorithm ]
  if opt-method = "Genetic Algorithm LR" [ genetic-algorithm-linear-ranks ]
  if opt-method = "Agent Tabu" [ hill-climb-with-agent-tabu ]
  if opt-method = "Population Tabu" [ hill-climb-with-pop-tabu ]
  if opt-method = "Harmony Search" [ harmony-search ]
  if opt-method = "Harmony Social Search" [ harmony-social-search ]
  
  set mean-fitness mean [fitness] of agents
  set max-fitness max [fitness] of agents
  
  tick

  if (ticks mod output-every) = 0 [Update-Plots]
  
end

to cross-entropy-method
  ; given population, update probability vector
  set ordered-list sort-by [([fitness] of ?1) > ([fitness] of ?2)] agents
  set order-statistic [fitness] of item (((selection - 1)/ 100) * count agents) ordered-list
  
  let freq count agents with [fitness >= order-statistic]
  let sumtotals array:from-list n-values n-nodes [0]
  ask agents [
    if fitness >= order-statistic [
      set sumtotals array:from-list (map [?1 + ?2] (array:to-list solution) (array:to-list sumtotals))
    ]
  ] 
  let weight1 (retention / 100)
  let weight2 1 - weight1
  set probabilities array:from-list (map [(weight2 * (?1 / freq)) + (weight1 * ?2)] (array:to-list sumtotals) (array:to-list probabilities))

  ; given probability vector, update population
  let chance-mutation mutation / 100
  ask agents [
    set solution array:from-list (map [ifelse-value (((? + chance-mutation) - (2 * ? * chance-mutation)) > random-float 1) [1] [0] ] (array:to-list probabilities))
    calc-agent-fitness
  ]
end

to via-vector
  ; given population, update probability vector
  let total-fitness sum [fitness] of agents
  let sumtotals array:from-list n-values n-nodes [0]
  ask agents [
    set sumtotals array:from-list (map [(?1 * (fitness)) + ?2] (array:to-list solution) (array:to-list sumtotals))
  ] 
  let weight1 (retention / 100)
  let weight2 1 - weight1
  set probabilities array:from-list (map [(weight2 * (?1 / total-fitness)) + (weight1 * ?2)] (array:to-list sumtotals) (array:to-list probabilities))
  
  ; given probability vector, update population
  let chance-mutation mutation / 100
  ask agents [
    set solution array:from-list (map [ifelse-value (((? + chance-mutation) - (2 * ? * chance-mutation)) > random-float 1) [1] [0] ] (array:to-list probabilities))
    calc-agent-fitness
  ]
end

to hill-climb
  ask agents [
    ; Agent performs random-walk hill climb
    set alt-fitness fitness
    let cur-node (random n-nodes)
    let alt-state array:item solution cur-node
    array:set solution cur-node (1 - alt-state)
    calc-agent-fitness
    if fitness < alt-fitness [
      ; roll back
      array:set solution cur-node alt-state
      set fitness alt-fitness
    ]
  ]
  
end

to simulated-annealing
  ask agents [
    ; Agent performs random-walk hill climb
    set alt-fitness fitness
    let cur-node (random n-nodes)
    let alt-state array:item solution cur-node
    array:set solution cur-node (1 - alt-state)
    calc-agent-fitness
    if fitness < alt-fitness [
      ifelse temperature > 0 [
        if 1 - (exp ((fitness - alt-fitness) / temperature)) > random-float 1 [
          ; roll back
          array:set solution cur-node alt-state
          set fitness alt-fitness
        ]
      ]
      [
        ; roll back
        array:set solution cur-node alt-state
        set fitness alt-fitness
      ]
    ]
  ]
  set temperature temperature * (1 - (2 ^ (-1 * heat-retention)))
  
end

to hill-climb-with-agent-tabu
  ; Hill climbing, random walk among solutions not on tabu list (stored in agent's memory)
  ; *** Will get stuck in a loop if memory is longer than solution length!
  ask agents [ ; Make copy of previous solutions
    set alt-solution array:from-list array:to-list solution
    set alt-fitness fitness
  ]
  ask agents [
    ; Agent performs random-walk hill climb
    set alt-fitness fitness
    let cur-node (random n-nodes)
    let alt-state array:item solution cur-node
    array:set solution cur-node (1 - alt-state)
;    show (word (member? solution memory) " # " solution " # " memory) ; debugging
    while [member? solution memory] [ ; If on tabu list, need another solution
      ;array:set solution cur-node alt-state ; arguably could leave this out (boredom leads to more radical experiments)
      set cur-node (random n-nodes)
      set alt-state array:item solution cur-node
      array:set solution cur-node (1 - alt-state)
;      show (word (member? solution memory) " # " solution " # " memory) ; debugging
    ]
    set memory fput (array:from-list array:to-list solution) memory
    if memory-length < (length memory) [set memory sublist memory 0 memory-length]
    
    calc-agent-fitness
    if fitness < alt-fitness [
      ; roll back
      ;array:set solution cur-node alt-state
      set solution array:from-list array:to-list alt-solution
      set fitness alt-fitness
    ]
  ]
  
end

to hill-climb-with-pop-tabu
  ; Hill climbing, random walk among solutions not on tabu list (stored in agent's memory)
  ; *** Will get stuck in a loop if memory is longer than solution length!
  ask agents [ ; Make copy of previous solutions
    set alt-solution array:from-list array:to-list solution
    set alt-fitness fitness
  ]
  ask agents [
    ; Agent performs random-walk hill climb
    set alt-fitness fitness
    let cur-node (random n-nodes)
    let alt-state array:item solution cur-node
    array:set solution cur-node (1 - alt-state)
    while [member? solution tabu-list] [ ; If on tabu list, need another solution
      ;array:set solution cur-node alt-state ; arguably could leave this out (boredom leads to more radical experiments)
      set cur-node (random n-nodes)
      set alt-state array:item solution cur-node
      array:set solution cur-node (1 - alt-state)
    ]
    set memory fput (array:from-list array:to-list solution) tabu-list
    if tabu-list-length < (length tabu-list) [set tabu-list sublist tabu-list 0 memory-length]
    
    calc-agent-fitness
    if fitness < alt-fitness [
      ; roll back
      ;array:set solution cur-node alt-state
      set solution array:from-list array:to-list alt-solution
      set fitness alt-fitness
    ]
  ]
  
end

to harmony-search
  ; Agent constructs solution from its harmony memory (a list of top-m past solutions), with some chance of mutation.
  ; If new solution is no worse than the worst in the list, drop one of the worst and add the new solution.
  ; Note: memory here is a list of lists, each first-order list consisting of fitness value and solution array.
  ; Memory is kept sorted in ascending order of fitness
  ; Last item in memory is returned as agent's preferred solution.
  let chance-mutation mutation / 100
  ask agents [
    ifelse (memory-length > length memory) [
      if (0 = length memory) [set memory fput (list fitness (array:from-list array:to-list solution)) memory]
      set solution array:from-list (n-values n-nodes [random 2])
      calc-agent-fitness
      set memory fput (list fitness (array:from-list array:to-list solution)) memory
      set memory sort-by [(item 0 ?1) <= (item 0 ?2)] memory
    ]
    [
      let cur-bit 0
      repeat n-nodes [
        array:set solution cur-bit (array:item (item 1 (one-of memory)) cur-bit)
        if chance-mutation > random-float 1 [array:set solution cur-bit (1 - array:item solution cur-bit)]
        set cur-bit cur-bit + 1
      ]
      calc-agent-fitness
      let num-inferior (length filter [item 0 ? <= fitness] memory)
      if num-inferior > 0 [
        let to-be-removed random num-inferior
        set memory remove-item to-be-removed memory
        set memory fput (list fitness (array:from-list array:to-list solution)) memory
        set memory sort-by [(item 0 ?1) <= (item 0 ?2)] memory
      ]
    ]
    set solution item 1 last memory
    set fitness item 0 last memory
  ]
end

to harmony-social-search
  ; 2 Agents co-construct solution from their harmony memory (a list of top-m past solutions), with some chance of mutation.
  ; If new solution is no worse than the worst in the list, drop one of the worst and add the new solution.
  ; Note: memory here is a list of lists, each first-order list consisting of fitness value and solution array.
  ; Memory is kept sorted in ascending order of fitness
  ; Last item in memory is returned as agent's preferred solution.
  let chance-mutation mutation / 100
  ask agents [
;    ifelse (memory-length > length memory) [
;      ifelse (0 = length memory) [
;        set memory fput (list fitness (array:from-list array:to-list solution)) memory
;      ]
;      [
;        set solution array:from-list (n-values n-nodes [random 2])
;        calc-agent-fitness
;        set memory fput (list fitness (array:from-list array:to-list solution)) memory
;        set memory sort-by [(item 0 ?1) <= (item 0 ?2)] memory
;      ]
;      
;    ]
;    [
      let alter one-of agents
;      let alter one-of other agents
      let switch-source false
      let cur-bit 0
      let chance-crossover crossover / 100
      repeat n-nodes [
        if chance-crossover > random-float 1 [set switch-source not switch-source]
        array:set solution cur-bit [(array:item (item 1 (one-of memory)) cur-bit)] of (ifelse-value switch-source [alter] [self])
        if chance-mutation > random-float 1 [array:set solution cur-bit (1 - array:item solution cur-bit)]
        set cur-bit cur-bit + 1
      ]
      calc-agent-fitness
      let num-inferior (length filter [item 0 ? <= fitness] memory)
      if num-inferior > 0 [
        let to-be-removed random num-inferior
        set memory remove-item to-be-removed memory
        set memory fput (list fitness (array:from-list array:to-list solution)) memory
        set memory sort-by [(item 0 ?1) <= (item 0 ?2)] memory
      ]
;    ]
    set solution item 1 last memory
    set fitness item 0 last memory
  ]
end

to genetic-algorithm
  let ego nobody
  let alter nobody
  let switch-source false
  let cur-bit 0
  let chance-crossover crossover / 100
  let chance-mutation mutation / 100
  let ordered-array array:from-list (sort-by [([fitness] of ?1) > ([fitness] of ?2)] agents)
  let total-fitness sum [fitness] of agents
  let cur-item 0
  let weights-sum 0

  ask agents [ ; Make copy of previous solutions
    set alt-solution array:from-list array:to-list solution
    set alt-fitness fitness
  ] 
  
  ask agents [
;    set ego self
;    set alter one-of other agents
    ; Stratified sampling to select source agent ego
    set weights-sum random-float total-fitness
    set cur-item -1
    while [weights-sum > 0] [
      set cur-item cur-item + 1
      set weights-sum weights-sum - [alt-fitness] of array:item ordered-array cur-item
    ]
    set ego array:item ordered-array cur-item
    
    ; Stratified sampling to select source agent alter
    set weights-sum random-float total-fitness
    set cur-item -1
    while [weights-sum > 0] [
      set cur-item cur-item + 1
      set weights-sum weights-sum - [alt-fitness] of array:item ordered-array cur-item
    ]
    set alter array:item ordered-array cur-item
    
    set cur-bit 0
    repeat n-nodes [
      if chance-crossover > random-float 1 [set switch-source not switch-source]
      array:set solution cur-bit [array:item alt-solution cur-bit] of (ifelse-value switch-source [alter] [ego])
      if chance-mutation > random-float 1 [array:set solution cur-bit (1 - array:item solution cur-bit)]
      set cur-bit cur-bit + 1
    ]
    calc-agent-fitness
  ]
end

to genetic-algorithm-linear-ranks
  let ego nobody
  let alter nobody
  let switch-source false
  let cur-bit 0
  let chance-crossover crossover / 100
  let chance-mutation mutation / 100
  let ordered-array array:from-list (sort-by [([fitness] of ?1) > ([fitness] of ?2)] agents)
  let denom (count agents) * (1 + count agents) / 2
  
  let cur-item 0
  let weights-sum 0

  ask agents [ ; Make copy of previous solutions
    set alt-solution array:from-list array:to-list solution
    set alt-fitness fitness
  ]
  
  ask agents [
;    set ego self
;    set alter one-of other agents
    ; Stratified sampling of linear function of ranks to select source agents ego and alter
    set ego array:item ordered-array ((count agents) - ((-1 + sqrt (1 + (4 * (random-float 1) * (count agents) * (1 + count agents)))) / 2))
    set alter array:item ordered-array ((count agents) - ((-1 + sqrt (1 + (4 * (random-float 1) * (count agents) * (1 + count agents)))) / 2))
    
    set cur-bit 0
    repeat n-nodes [
      if chance-crossover > random-float 1 [set switch-source not switch-source]
      array:set solution cur-bit [array:item alt-solution cur-bit] of (ifelse-value switch-source [alter] [ego])
      if chance-mutation > random-float 1 [array:set solution cur-bit (1 - array:item solution cur-bit)]
      set cur-bit cur-bit + 1
    ]
    calc-agent-fitness
  ]
end

to print-probabilities
  print (word "Probability vector: " (map [precision ? 3] (array:to-list probabilities)))
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to Setup-Plots
  set-current-plot "Fitness"
  set-current-plot-pen "Mean"
  set-plot-pen-interval output-every
  set-current-plot-pen "Max"
  set-plot-pen-interval output-every
  set-current-plot-pen "Order-Stat"
  set-plot-pen-interval output-every
  
  set-current-plot "Fitness-Histogram"
  set-plot-pen-interval 0.05
  histogram [fitness] of agents
end

to Update-Plots
  set-current-plot "Fitness"
  set-current-plot-pen "Mean"
  plot mean-fitness
  set-current-plot-pen "Max"
  plot max-fitness
  set-current-plot-pen "Order-Stat"
  plot order-statistic
  
  set-current-plot "Fitness-Histogram"
  set-plot-pen-interval 0.05
  histogram [fitness] of agents
end

@#$#@#$#@
GRAPHICS-WINDOW
213
10
652
470
16
16
13.0
1
10
1
1
1
0
1
1
1
-16
16
-16
16
0
0
1
ticks

SLIDER
8
120
180
153
K-inputs
K-inputs
0
15
5
1
1
NIL
HORIZONTAL

SLIDER
8
84
180
117
N-nodes
N-nodes
1
100
20
1
1
NIL
HORIZONTAL

PLOT
656
163
929
313
Fitness
Iterations (ticks)
Fitness
0.0
10.0
0.0
1.0
true
true
PENS
"Mean" 1.0 0 -13345367 true
"Max" 1.0 0 -16777216 true
"Order-Stat" 1.0 0 -955883 true

SLIDER
8
48
180
81
Number-of-Agents
Number-of-Agents
1
100
100
1
1
NIL
HORIZONTAL

BUTTON
7
461
71
494
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
75
461
138
494
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
656
316
736
361
Agent Mean
mean-fitness
3
1
11

MONITOR
739
316
812
361
Agent Max
max-fitness
3
1
11

PLOT
657
10
857
160
Fitness-Histogram
Fitness
# Agents
0.0
1.0
0.0
5.0
true
false
PENS
"default" 1.0 1 -16777216 true

INPUTBOX
6
572
161
632
Output-Every
1
1
0
Number

TEXTBOX
11
4
161
44
Kauffman's NK Fitness Landscapes
16
0.0
1

TEXTBOX
656
364
806
382
Initial Values:
11
0.0
1

MONITOR
655
382
735
427
Agent Mean
initial-mean-fitness
3
1
11

MONITOR
738
382
811
427
Agent Max
initial-max-fitness
3
1
11

MONITOR
656
454
736
499
Agent Mean
100 * ((mean-fitness / initial-mean-fitness) - 1)
1
1
11

TEXTBOX
660
435
810
453
% Improvement:
11
0.0
1

MONITOR
739
454
812
499
Agent Max
100 * ((max-fitness / initial-max-fitness) - 1)
1
1
11

BUTTON
6
498
89
531
Reset Agents
reset-agents
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
7
206
179
239
Selection
Selection
1
100
5
1
1
NIL
HORIZONTAL

SLIDER
7
242
179
275
Retention
Retention
0
100
80
1
1
NIL
HORIZONTAL

BUTTON
142
461
208
494
Go Once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

CHOOSER
8
157
210
202
Opt-Method
Opt-Method
"Random-Walk Hill Climb" "Simulated Annealing" "Cross-Entropy Method" "Weighted Probability Vector" "Genetic Algorithm" "Genetic Algorithm LR" "Agent Tabu" "Population Tabu" "Harmony Search" "Harmony Social Search"
9

BUTTON
6
535
102
568
Print Vector
print-probabilities
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
105
535
190
568
Print Max
print (word \"Current best: \" (array:to-list ([solution] of one-of agents with [fitness = max-fitness])))\n
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
7
278
179
311
Mutation
Mutation
0
100
5
1
1
NIL
HORIZONTAL

SLIDER
7
314
179
347
Heat-Retention
Heat-Retention
0
10
1
1
1
NIL
HORIZONTAL

SLIDER
7
350
179
383
Crossover
Crossover
0
100
5
1
1
NIL
HORIZONTAL

SLIDER
7
385
179
418
Memory-Length
Memory-Length
0
20
1
1
1
NIL
HORIZONTAL

SLIDER
7
421
179
454
Tabu-List-Length
Tabu-List-Length
0
100
100
5
1
NIL
HORIZONTAL

INPUTBOX
165
572
320
632
Max-ticks
2000
1
0
Number

@#$#@#$#@
WHAT IS IT?
-----------
Stuart Kauffman's NK Fitness Landscapes.

As described in Kauffman (1993, 1995, 2000) among other places. This is the most basic form of the fitness model. (So no patches, species, alternative network topologies, phenotypical functions etc.)

This NetLogo version (C) Christopher J Watts, 2011.

HEURISTIC SEARCH ALGORITHMS
---------------------------

Random-Walk Hill Climbing: flip a randomly chosen variable; if fitness does not get worse, keep the new value, else flip it back.

Cross-Entropy Method: Use a probability vector to generate a population of solutions; use the information contained in the top-n% solutions to update the probability vector.

Weighted Probability Vector: Use a probability vector to generate a population of solutions; weight the information contained in solutions by fitness to update the probability vector.

Genetic Algorithm: Each tick agents are given a new generation of solutions, based upon solutions selected from the previous generation. During construction of a new solution there is a the chance of mutation of individual bits and crossover between pairs of solutions. Selection of solutions uses stratified sampling based on fitness values.

Genetic Algorithm LR: As genetic algorithm, but selects previous solutions using stratified sampling of a linear function of rank order based on fitness.

Agent Tabu: Similar to random-walk hill climbing, but each agent maintains a memory of its most recent solutions and forces its new solution to be distinct from any on the tabu list - i.e. its memory.

Population Tabu: The tabu list consists of the whole population's most recent solutions. Thus the agents constrain each other's search efforts.

Harmony Search: Each agent constructs a new solution by sampling each bit from a memory of its top-m past solutions. There is also a chance of mutation for each bit. The new solution is evaluated. If it is no worse than the worst solution in memory, one of the worst solutions is removed from memory, and the new solution is added to memory. Memory is kept sorted in ascending order of fitness, so the last item in memory has the best fitness value. When not active, an agent's solution and fitness value is set to this last item.

Harmony Social Search: Similar to Harmony Search, but pairs of agents co-construct solutions. During construction of a new solution, there is a chance of crossover with information from the other agent's memory.

HOW IT WORKS
------------
There are N nodes. Each node has a binary variable, its current state. Each node takes input from K input nodes, plus itself. Each node has a fitness table, listing the contribution it makes to fitness given the current states of all its input nodes, including itself. Input nodes are assigned at randomly uniformly. Tables of fitness contributions are populated from a uniform distribution in the range [0, 1). Given a combination of all N node states, the N contributions can be averaged to compute a single fitness value.


HOW TO USE IT
-------------
"setup-NK" defines the input tables and fitness tables.
"calc-agent-fitness" calculates for the current agent a fitness value from a given solution. The fitness value is returned in the agent's attribute "fitness". (Though it could have been returned using "report " instead.) The solution is contained in an array called "solution". (Though this could have been a global, instead of being agent-specific.)

"setup" creates a population of agent optimisers.
"go" runs for each agent a heuristic search algorithm, in the first case "random-walk hill climbing".

For a given population of agent optimisers, the population mean and max can be output periodically.

THINGS TO NOTICE
----------------
Agents improve their fitness over time, but improvements become harder to obtain. Eventually fitness may plateau, as every agent has reached a peak fitness, or local optimum solution.

Given sufficiently many agents, at values of K > 0 it is likely that the agent mean will not reach the agent max. This reflects the fact that the agents have not all reached the same local optimum. As we try increasing K, the expected number of local optima per landscape increases at a super-linear rate.

THINGS TO TRY
-------------
Use BehaviorSpace to find out what values for mean and max fitness you get given different size problems (N), difficulty levels (controlled by K) and population sizes.

EXTENDING THE MODEL
-------------------
Try different heuristic search algorithms than random-walk hill climbing: steepest-path hill climbing, simulated annealing, tabu search, cross-entropy method / ant-colony optimisation, harmony search, genetic algorithms etc...


NETLOGO FEATURES
----------------
Note how compact the definition and calculation of NK fitness is in NetLogo.


RELATED MODELS
--------------
Boolean constraint satisfaction problems (K-Sat) can also be defined very economically.

NK fitness models have provided the starting point for various simulation models, some of them modifying the basic definition. See for examples: Kauffman et al (2000), Levinthal (e.g. 1997) on strategic decision making, Frenken (various) on technological evolution, Lazer & Friedman (2007) on collective learning, and Watts & Gilbert (forthcoming) on science models.

CREDITS AND REFERENCES
----------------------
Kauffman, Stuart (1993) "The Origins of Order: Self-Organization and Selection in Evolution". New York: OUP

Kauffman, Stuart (1995) "At home in the universe: the search for laws of complexity". London: Penguin.

Kauffman, Stuart (2000) "Investigations". Oxford : Oxford University Press

Kauffman, Stuart, Jose Lobo & William G Macready (2000) "Optimal search on a technology landscape". Journal of Economic Behavior & Organization 43 141-166

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="experiment-VarK" repetitions="100" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <exitCondition>ticks = 2000</exitCondition>
    <metric>timer</metric>
    <metric>mean-fitness</metric>
    <metric>max-fitness</metric>
    <metric>initial-mean-fitness</metric>
    <metric>initial-max-fitness</metric>
    <enumeratedValueSet variable="K-inputs">
      <value value="0"/>
      <value value="1"/>
      <value value="2"/>
      <value value="3"/>
      <value value="4"/>
      <value value="5"/>
      <value value="6"/>
      <value value="7"/>
      <value value="8"/>
      <value value="9"/>
      <value value="10"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Output-Every">
      <value value="2000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="N-nodes">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Number-of-Agents">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Max-ticks">
      <value value="500"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment" repetitions="50" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <exitCondition>ticks = 50</exitCondition>
    <metric>timer</metric>
    <metric>count agents</metric>
    <metric>initial-mean-fitness</metric>
    <metric>initial-max-fitness</metric>
    <metric>mean-fitness</metric>
    <metric>max-fitness</metric>
    <metric>((mean-fitness / initial-mean-fitness) - 1)</metric>
    <metric>((max-fitness / initial-max-fitness) - 1)</metric>
    <metric>order-statistic</metric>
    <enumeratedValueSet variable="N-nodes">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Number-of-Agents">
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Output-Every">
      <value value="50"/>
    </enumeratedValueSet>
    <steppedValueSet variable="Retention" first="5" step="10" last="95"/>
    <steppedValueSet variable="Selection" first="5" step="10" last="95"/>
    <steppedValueSet variable="K-inputs" first="0" step="1" last="9"/>
    <enumeratedValueSet variable="Max-ticks">
      <value value="500"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Opt-Method">
      <value value="&quot;Cross-Entropy Method&quot;"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment-RWHC" repetitions="50" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <exitCondition>ticks = 50</exitCondition>
    <metric>timer</metric>
    <metric>count agents</metric>
    <metric>initial-mean-fitness</metric>
    <metric>initial-max-fitness</metric>
    <metric>mean-fitness</metric>
    <metric>max-fitness</metric>
    <metric>((mean-fitness / initial-mean-fitness) - 1)</metric>
    <metric>((max-fitness / initial-max-fitness) - 1)</metric>
    <metric>order-statistic</metric>
    <enumeratedValueSet variable="N-nodes">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Number-of-Agents">
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Output-Every">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Retention">
      <value value="75"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Selection">
      <value value="5"/>
    </enumeratedValueSet>
    <steppedValueSet variable="K-inputs" first="0" step="1" last="9"/>
    <enumeratedValueSet variable="Max-ticks">
      <value value="500"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Opt-Method">
      <value value="&quot;Random-Walk Hill Climb&quot;"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment-CEM" repetitions="10" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <exitCondition>ticks = 50</exitCondition>
    <metric>timer</metric>
    <metric>count agents</metric>
    <metric>initial-mean-fitness</metric>
    <metric>initial-max-fitness</metric>
    <metric>mean-fitness</metric>
    <metric>max-fitness</metric>
    <metric>((mean-fitness / initial-mean-fitness) - 1)</metric>
    <metric>((max-fitness / initial-max-fitness) - 1)</metric>
    <metric>order-statistic</metric>
    <enumeratedValueSet variable="Opt-Method">
      <value value="&quot;Cross-Entropy Method&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="N-nodes">
      <value value="20"/>
    </enumeratedValueSet>
    <steppedValueSet variable="K-inputs" first="0" step="1" last="9"/>
    <enumeratedValueSet variable="Number-of-Agents">
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Heat-Retention">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Crossover">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Mutation">
      <value value="0"/>
      <value value="1"/>
      <value value="2"/>
      <value value="4"/>
      <value value="8"/>
      <value value="16"/>
    </enumeratedValueSet>
    <steppedValueSet variable="Retention" first="5" step="10" last="95"/>
    <steppedValueSet variable="Selection" first="5" step="10" last="95"/>
    <enumeratedValueSet variable="Memory-Length">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Tabu-List-Length">
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Output-Every">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Max-ticks">
      <value value="500"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment-HSS" repetitions="1000" runMetricsEveryStep="false">
    <setup>set memory-length int (100 / number-of-agents)
setup</setup>
    <go>go</go>
    <metric>timer</metric>
    <metric>count agents</metric>
    <metric>initial-mean-fitness</metric>
    <metric>initial-max-fitness</metric>
    <metric>mean-fitness</metric>
    <metric>max-fitness</metric>
    <metric>((mean-fitness / initial-mean-fitness) - 1)</metric>
    <metric>((max-fitness / initial-max-fitness) - 1)</metric>
    <metric>order-statistic</metric>
    <metric>memory-length</metric>
    <enumeratedValueSet variable="N-nodes">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="K-inputs">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Number-of-Agents">
      <value value="1"/>
      <value value="2"/>
      <value value="4"/>
      <value value="5"/>
      <value value="10"/>
      <value value="20"/>
      <value value="25"/>
      <value value="50"/>
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Mutation">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Crossover">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Memory-Length">
      <value value="20"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Tabu-List-Length">
      <value value="100"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Heat-Retention">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Retention">
      <value value="80"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Selection">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Output-Every">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Max-ticks">
      <value value="100"/>
      <value value="500"/>
      <value value="2000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="Opt-Method">
      <value value="&quot;Harmony Social Search&quot;"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@